start - Ejecutar otros archivos por lotes

Mantenido el 18 de octubre de 2026

El comando start inicia otro programa o archivo por lotes.

Es especialmente útil en archivos por lotes cuando quieres ejecutar algo de forma asíncrona en otra ventana, esperar a que termine antes de continuar, o abrir una URL o un archivo asociado.

Sintaxis básica del comando start

start <"título"> [/d <ruta>] [/i] [{/min | /max}] [{/low | /normal | /high | /realtime | /abovenormal | /belownormal}] [/wait] [/b] [comando o programa] [argumentos]

Por defecto, start pasa a la siguiente línea sin esperar a que termine el proceso iniciado.

La primera cadena entre comillas se interpreta como el título

start trata la primera cadena entre comillas como el título de la ventana. Al iniciar un programa cuya ruta contiene espacios, coloca primero un título vacío, como en start "" "C:\My Scripts\job.cmd".

Uso básico

Iniciar otro archivo por lotes de forma asíncrona

@echo off

echo Se inició caller.cmd.
start "" callee.cmd
echo Terminó caller.cmd.

@echo off

echo Se inició callee.cmd.
timeout /t 5 /nobreak > nul
echo Terminó callee.cmd.

－ □ ×

Consola de comandos

Microsoft Windows [Version xx.x.xxxxx.xxx]

C:\users\user>caller.cmd

Se inició caller.cmd.

Terminó caller.cmd.

C:\users\user>

－ □ ×

Consola de comandos

Microsoft Windows [Version xx.x.xxxxx.xxx]

C:\users\user>

Se inició callee.cmd.

Terminó callee.cmd.

おすすめ書籍※ 広告を含む場合があります

中小企業経営者のためのRPA入門 RPA導入を成功させる方法

60分でわかる！ AIエージェント　超入門

コマンドラインの黒い画面が怖いんです。

知識・才能ゼロでもらく～に月10万円稼ぐ! よくわかるAI副業超入門

callee.cmd se ejecuta en otra ventana, por lo que caller.cmd puede terminar sin esperar.

El orden de la salida no está garantizado

En la ejecución asíncrona, el orden en que aparece la salida puede variar según el entorno y el momento. No asumas un orden fijo.

Ejecutar con argumentos

start "" callee.cmd 1
start "" callee.cmd 2

callee.cmd puede recibir los argumentos como %1, %2, etc.

@echo off

echo Se inició callee.cmd.
echo Esta es la ejecución número %1.
timeout /t 3 /nobreak > nul
echo Terminó callee.cmd.

Iniciar un programa cuya ruta contiene espacios

start "" "C:\My Scripts\daily backup.cmd"

Es donde más se equivoca la gente con start. El primer "" es el título y la cadena entre comillas siguiente es el programa que se ejecuta.

Abrir una URL o un archivo asociado

Si especificas una URL o un documento, se abre con la aplicación asociada (por ejemplo, el navegador predeterminado).

start "" https://example.com
start "" report.pdf

Opciones más usadas

Opción	Descripción
`/wait`	Espera a que termine el programa iniciado
`/b`	Inicia sin crear una ventana nueva
`/min`	Inicia minimizado
`/max`	Inicia maximizado
`/d ruta`	Define el directorio de trabajo del programa iniciado
`/low` `/high`, etc.	Define la prioridad del proceso

`/wait` - esperar a que termine antes de continuar

start "" /wait installer.exe /S
echo Esta línea se ejecuta cuando termina la instalación.

`/b` - iniciar sin abrir una ventana nueva

start "" /b tool.exe --quiet

Con /b no se abre una ventana nueva del símbolo del sistema. Los programas que no son de interfaz gráfica escriben su salida en la misma ventana que el llamador.

Para ejecutar archivos por lotes en orden, call puede ser mejor opción

Si solo quieres llamar a otro archivo por lotes en la misma ventana y continuar cuando termine, call suele encajar mejor que start /wait.

Diferencia con el comando call

Comando	Uso principal
`start`	Ejecución asíncrona, abrir una ventana nueva, abrir URL o archivos asociados
`call`	Llamar a otro archivo por lotes y continuar en la misma ventana cuando termine