sfc / DISM - Reparar archivos del sistema

Cuando Windows se vuelve inestable o funciones estándar como Configuración o el menú Inicio dejan de funcionar correctamente, el Comprobador de archivos de sistema (sfc) es una de las primeras herramientas que conviene probar. Analiza los archivos protegidos del sistema de Windows y sustituye por la versión correcta los que estén dañados o hayan sido modificados.

Si sfc no puede solucionar el problema, combínelo con el comando DISM, que repara el almacén de componentes que sfc utiliza como origen. Este artículo explica ambos comandos y el orden en que conviene ejecutarlos.

Preparación: ejecutar como administrador

sfc y DISM solo funcionan en un Símbolo del sistema ejecutado como administrador. Si ejecuta sfc sin permisos de administrador, muestra un error indicando que debe ejecutar una sesión de consola como administrador, y el análisis no se inicia.

Para saber cómo abrir el Símbolo del sistema como administrador, consulte

Sintaxis básica de sfc

sfc [/scannow] [/verifyonly] [/scanfile=<archivo>] [/verifyfile=<archivo>]
    [/offbootdir=<unidad> /offwindir=<carpeta_de_Windows>] [/offlogfile=<archivo_de_registro>]

Analizar y reparar todo el sistema

sfc /scannow

Mientras se ejecuta, el progreso se muestra como «Verificación al xx % completada». Según el equipo, puede tardar desde varias decenas de minutos hasta una hora o más, así que no cierre la ventana ni apague el PC durante el análisis.

Cómo interpretar los mensajes de resultado

Al terminar, se muestra uno de los siguientes mensajes.

Solo analizar, sin reparar

Si solo quiere conocer el estado del sistema sin modificarlo, use /verifyonly.

sfc /verifyonly

Analizar y reparar un archivo concreto

Si sabe qué archivo está dañado, puede indicarlo con su ruta completa.

sfc /scanfile=C:\Windows\System32\kernel32.dll

sfc /verifyfile=C:\Windows\System32\kernel32.dll

Consultar los detalles en el registro

Los detalles de sfc se guardan en C:\Windows\Logs\CBS\CBS.log. Este archivo es muy grande, por lo que resulta más fácil de leer si extrae solo las líneas de sfc (las marcadas con [SR]).

findstr /c:"[SR]" "%windir%\Logs\CBS\CBS.log" > "%userprofile%\Desktop\sfcdetails.txt"

> es la redirección, que escribe la salida en un archivo. Para más detalles, consulte

Cuando sfc no lo soluciona: reparar el origen con DISM

sfc repara los archivos usando las copias guardadas en el almacén de componentes (C:\Windows\WinSxS). Si el propio almacén de componentes está dañado, sfc no puede reparar nada. En ese caso, use DISM (Deployment Image Servicing and Management) para reparar el almacén de componentes.

DISM /Online /Cleanup-Image /RestoreHealth

De forma predeterminada, /RestoreHealth obtiene los archivos de reparación de Windows Update, por lo que se necesita conexión a Internet. Puede tardar mucho y el porcentaje puede parecer detenerse a mitad del proceso.

Orden de ejecución

La recomendación de Microsoft es reparar primero el origen con DISM y después ejecutar sfc. Otro método habitual es probar primero sfc, pasar a DISM solo si no funciona y ejecutar sfc una vez más. En cualquier caso, termine confirmando con sfc /scannow que el problema se ha resuelto.

Los pasos al ejecutar primero DISM son:

1. Ejecute DISM /Online /Cleanup-Image /RestoreHealth
2. Cuando termine, ejecute sfc /scannow
3. Reinicie y compruebe si los síntomas han mejorado

DISM /Online /Cleanup-Image /RestoreHealth
sfc /scannow

Ejecutarlo desde un archivo por lotes

Reunir los pasos en un archivo por lotes que se ejecute con permisos de administrador evita escribirlos cada vez.

@echo off
net session >nul 2>&1
if errorlevel 1 (
    echo Ejecute esto como administrador.
    pause
    exit /b 1
)

echo === Analisis y reparacion del origen con DISM ===
DISM /Online /Cleanup-Image /RestoreHealth

echo.
echo === Analisis y reparacion de archivos del sistema con sfc ===
sfc /scannow

echo.
echo Terminado. Revise los resultados y reinicie si es necesario.
pause

net session falla sin permisos de administrador, por lo que se usa a menudo como comprobación sencilla de permisos. Sin embargo, en un entorno donde el servicio Servidor está detenido, puede fallar incluso para un administrador. Para volver a lanzar un script automáticamente con permisos de administrador, consulte

DISM guarda registros detallados en C:\Windows\Logs\DISM\dism.log. Si DISM falla, consulte también este archivo.

Resumen

Artículos relacionados

Preguntas de práctica