Mensajes de error y soluciones

Mantenido el
Tabla de contenidos

Los mensajes de error del Símbolo del sistema son breves y a menudo no dicen qué está mal realmente. Un mismo mensaje puede tener varias causas, como un error de escritura, falta de permisos o un espacio en una ruta.

Esta página explica qué significan los mensajes de error más habituales, cómo acotar la causa y cómo solucionar cada uno.

Pegue un mensaje de error para encontrar la causa

Pegue el mensaje tal como aparece y la herramienta mostrará de qué error se trata y qué probar primero. Puede pegar varias líneas a la vez.

Buscar la causa de un mensaje de error

Pegue el mensaje que muestra el Símbolo del sistema, completo o en parte.

Probar un ejemplo:

La comprobación se hace en esta página. Lo que pegue no se envía a ningún sitio.

Pegue un mensaje de error y aquí aparecerán la causa y la solución.

Referencia rápida: mensajes de error habituales

Mensaje de errorCausas habitualesQué probar primero
’…’ no se reconoce como un comando interno o externo, programa o archivo por lotes ejecutable.Error de escritura, no instalado, no está en el PATH, espacio en una rutaComprobar con where nombre
Acceso denegado.Requiere administrador, archivo de solo lectura, sin permisoEjecutar como administrador, attrib -r
La operación solicitada requiere elevación.No se ejecuta como administradorVolver a abrir como administrador
El sistema no puede encontrar la ruta especificada.La carpeta no existe, la carpeta actual no es la esperadaComprobar con cd, usar cd /d "%~dp0"
El sistema no puede encontrar el archivo especificado.Nombre o extensión distintos, ubicación equivocadaVer los nombres reales con dir /a /b
La sintaxis del nombre de archivo, del nombre de directorio o de la etiqueta del volumen no es correcta.Caracteres no permitidos en nombres (: / ?, etc.)Quitar : y / de %time% / %date%
La sintaxis del comando no es correcta.Opciones mal escritas, paréntesis desparejadosComprobar con comando /?
No se esperaba … en este momento.Variable vacía, ) dentro de un bloque, %i en un archivo por lotesPoner las variables entre comillas, usar %%i
El proceso no tiene acceso al archivo porque está siendo utilizado por otro proceso.Otra aplicación tiene el archivo abiertoCerrarla, buscarla con resmon
El directorio no está vacío.rmdir sobre una carpeta con contenidormdir /s /q
Ya existe el subdirectorio o el archivo ….La carpeta ya existeComprobar antes con if not exist
Existe un nombre de archivo duplicado o no se encuentra el archivo.El nombre nuevo de ren ya está en usoComprobar los nombres con dir
El sistema no puede encontrar la unidad especificada.La unidad no está conectadaComprobar con net use
La línea de entrada es demasiado larga.Una línea superó los 8191 caracteresDejar de añadir al PATH repetidamente

Causas y soluciones por mensaje de error

“no se reconoce como un comando interno o externo”

Es el error más habitual. Significa que no se encontró el comando o programa con el nombre escrito.

- □ ×
Ícono de la consola de comandos
Consola de comandos
Microsoft Windows [Version xx.x.xxxxx.xxx]
(c) 2026 Ribbit App Development All rights reserved.
 
C:\users\user>python --version
‘python’ no se reconoce como un comando interno o externo,
programa o archivo por lotes ejecutable.

El Símbolo del sistema busca el nombre en este orden y muestra este error si no lo encuentra en ninguna parte:

  1. Comandos integrados como dir y copy
  2. La carpeta actual
  3. Las carpetas de la variable de entorno PATH (probando extensiones como .exe, .bat y .cmd)

Primero, compruebe con where si el comando existe en algún sitio.

where python
echo %PATH%

Si where no encuentra nada, o lo encuentra pero sigue sin ejecutarse, use esta tabla para acotar la causa.

SituaciónEjemploSolución
Error de escrituraipconfgEscribir el nombre correctamente
Una ruta con espacios no está entre comillas'C:\Program' no se reconoce…Poner la ruta completa entre comillas: "C:\Program Files\app\app.exe"
El programa no está instalado o no está en el PATHpython git node javaInstalarlo y añadirlo al PATH (variables de entorno y PATH)
La ventana se abrió antes de cambiar el PATHJusto después de instalarAbrir un Símbolo del sistema nuevo
Se escribió un comando de Linux o macOSls cat grepUsar los comandos de la tabla de abajo
Una característica de Windows está desactivada o se eliminótelnet wmicActivarla o usar un sustituto
& o `` se interpretó como separadorecho A & B da 'B' no se reconoce
Solo falla la primera línea de un archivo por lotes'´╗┐@echo' con caracteres extraños delanteGuardarlo de nuevo sin BOM (ver abajo)
Precaución

Un archivo por lotes guardado como “UTF-8 con BOM” empieza con un carácter invisible llamado BOM. El Símbolo del sistema lo lee como parte del nombre del comando, así que @echo off en la primera línea falla con un error como '´╗┐@echo' no se reconoce…. Vuelva a guardar el archivo como “UTF-8” (sin BOM) o “ANSI”. Consulte cómo evitar caracteres ilegibles para elegir la codificación.

Comandos de Linux / macOS y sus equivalentes

EscribióEn el Símbolo del sistema, use
lsdir
cattype
grepfindstr
rm / rm -rdel / rmdir /s
cpcopy (robocopy para carpetas completas)
mvmove
touch archivotype nul >> archivo
clearcls
pwdcd
whichwhere
ps / killtasklist / taskkill
ifconfigipconfig
man comandocomando /?
sudoEjecutar el Símbolo del sistema como administrador

En Windows 11 versión 24H2 y posteriores, sudo se puede activar en Configuración → Sistema → Para programadores.

Nombres de comando que dan este error con frecuencia

ComandoCausa y solución
python / pipNo se marcó “Add python.exe to PATH” al instalar. Si Python está instalado, py (el lanzador de Python) y py -m pip suelen funcionar
gitGit for Windows no está instalado. Instálelo con winget install --id Git.Git -e y abra una ventana nueva
node / npmNode.js no está instalado, o la ventana se abrió antes de instalarlo
java / javacNo hay ningún JDK instalado, o su carpeta bin no está en el PATH
codeNo se activó “Agregar a PATH” al instalar VS Code
wingetEl “Instalador de aplicaciones” de Microsoft Store está desactualizado. Actualícelo en la Store
wmicHerramienta en proceso de retirada; las versiones recientes de Windows 11 pueden no incluirla de forma predeterminada. Sustitúyala por Get-CimInstance de PowerShell
telnetEl cliente Telnet está desactivado. Actívelo como administrador con dism /online /Enable-Feature /FeatureName:TelnetClient

“Acceso denegado”

No tiene permiso para la operación. Hay tres causas principales.

CausaSituación típicaSolución
Se requieren derechos de administradorCambios en C:\Windows o C:\Program Files, gestión de servicios, comandos netEjecutar como administrador
Atributo de solo lectura o de sistemadel no puede eliminar un archivoQuitar el atributo con attrib -r archivo o usar del /f
Sin permiso NTFSCarpeta de otro usuario, archivos copiados de otro equipoComprobar los permisos con icacls
attrib "C:\work\report.txt"
attrib -r "C:\work\report.txt"
icacls "C:\work\report.txt"

Si attrib muestra R (solo lectura), quítelo con attrib -r. Los comandos net muestran “Error de sistema 5.” junto con este mensaje; significa lo mismo y normalmente se resuelve ejecutando como administrador.

“La operación solicitada requiere elevación”

Aparece al iniciar desde un Símbolo del sistema normal un programa que solo funciona como administrador. El mensaje de sfc que indica que debe ser administrador en una sesión de consola tiene la misma causa.

Puede comprobar si la ventana actual se ejecuta como administrador con el siguiente comando (aprovecha que net session falla si no es administrador).

net session >nul 2>&1 && echo Administrador || echo Usuario estandar

Si muestra “Usuario estandar”, vuelva a abrir el Símbolo del sistema como administrador. Para que un archivo por lotes se vuelva a iniciar como administrador automáticamente, consulte elevación automática de archivos por lotes.

“El sistema no puede encontrar la ruta especificada”

La carpeta indicada, o una carpeta intermedia, no existe. Además de los errores de escritura, estas tres causas son habituales:

  • La carpeta actual no es la esperada: las rutas relativas (como data\input.txt) parten de la carpeta actual. En particular, al ejecutar un archivo por lotes como administrador, la carpeta actual pasa a ser C:\Windows\System32, así que ya no se encuentran los archivos que están junto al archivo por lotes.
  • La carpeta de destino no existe: copy y move no crean una carpeta de destino que falte. Créela antes con mkdir.
  • No se ve una unidad de red: las unidades de red asignadas como usuario normal pueden no verse desde un Símbolo del sistema ejecutado como administrador. Use una ruta UNC como \\servidor\recurso.

En un archivo por lotes, moverse primero a su propia carpeta hace que funcione igual desde cualquier sitio.

@echo off
cd /d "%~dp0"

%~dp0 es la ruta de la carpeta que contiene el archivo por lotes. Consulte obtener y cambiar el directorio actual para más detalles.

“El sistema no puede encontrar el archivo especificado”

No existe ningún archivo con ese nombre. dir muestra “No se encuentra el archivo” y del muestra “No se pudo encontrar …” en la misma situación.

  • La extensión es distinta: si el Explorador oculta las extensiones, un archivo que cree que es memo.txt puede ser en realidad memo.txt.txt.
  • Archivos ocultos: dir no muestra los archivos ocultos de forma predeterminada.
  • Busca en el lugar equivocado: compruebe la carpeta actual (ver la sección anterior).
dir /a /b
where /r . memo*.txt

dir /a /b lista los nombres incluidos los archivos ocultos, y where /r . busca en la carpeta actual y sus subcarpetas.

“No se ha encontrado la ruta de acceso de la red”

Aparece con net use o al acceder a \\servidor\recurso cuando no se puede llegar al otro equipo (error de sistema 53). Causas habituales: el nombre del equipo es incorrecto, el equipo está apagado, el uso compartido de archivos está desactivado o un firewall bloquea la conexión.

ping nombreservidor
net view \\nombreservidor

Si ping falla, el problema es la red o la resolución de nombres. Si ping funciona pero net view falla, el problema es la configuración del uso compartido.

“La sintaxis del nombre de archivo, del nombre de directorio o de la etiqueta del volumen no es correcta”

El nombre o la ruta contiene un carácter no permitido (\ / : * ? " < > |). Un caso habitual es usar %date% o %time% directamente en un nombre de archivo.

NG.bat
rem El ":" de 12:34:56,78 acaba en el nombre de archivo y provoca el error
echo test> log_%time%.txt

Quite : y / antes de usarlos.

OK.bat
set t=%time: =0%
set t=%t::=%
set d=%date:/=%
echo test> log_%d%_%t:~0,6%.txt

%variable:antiguo=nuevo% reemplaza caracteres. El formato de %date% depende de la configuración regional, así que consulte obtener la fecha y la hora para un método que no dependa del formato. Las comillas desparejadas también provocan este error.

“La sintaxis del comando no es correcta”

Las opciones o los argumentos no coinciden con la sintaxis del comando.

  • Opciones mal escritas o en otro orden → compruebe la sintaxis correcta con comando /?.
  • Paréntesis desparejados en if o for.
  • Una variable vacía deja al comando con argumentos de menos.

Si no sabe en qué línea del archivo por lotes ocurre, cambie temporalmente @echo off al principio por rem @echo off y ejecútelo. Cada línea se muestra al ejecutarse, así que la línea mostrada justo antes del error es la causa probable.

“No se esperaba … en este momento”

Al leer un if, un for o un bloque entre paréntesis, cmd encontró un carácter que no puede aparecer ahí. El texto que muestra el mensaje es la pista.

MensajeCausa habitualSolución
No se esperaba i en este momento.Escribió for %i dentro de un archivo por lotesUse %%i en archivos por lotes (comando for)
No se esperaba ==abc en este momento.Comparó una variable vacía (if %var%==abc)Ponga ambos lados entre comillas: if "%var%"=="abc"
No se esperaba \Microsoft en este momento.Se expandió %PATH% dentro de un bloque y el ) de (x86) cerró el bloquePonga la asignación entre comillas: set "PATH=%PATH%;C:\tools"
No se esperaba ) en este momento.Un echo dentro de un bloque contiene )Escápelo como ^)

Si además las variables dentro de un bloque no cambian como espera, consulte expansión retrasada.

“El proceso no tiene acceso al archivo porque está siendo utilizado por otro proceso”

Otra aplicación o proceso tiene abierto el archivo (o la carpeta), así que no se puede eliminar, mover ni sobrescribir. Casos típicos: un archivo abierto en Excel, el panel de vista previa del Explorador o una carpeta que es la carpeta actual de otro Símbolo del sistema.

Si no sabe qué proceso lo usa, el Monitor de recursos puede encontrarlo.

resmon

En la pestaña CPU, escriba el nombre del archivo en el cuadro de búsqueda de “Identificadores asociados” para ver qué procesos lo tienen abierto.

“ERROR: no se encontró el proceso ”…""

taskkill /im muestra este mensaje cuando ningún proceso en ejecución tiene el nombre de imagen indicado. El nombre de imagen es el nombre del ejecutable con .exe y puede ser distinto del título de la ventana o del nombre visible de la aplicación (por ejemplo, Edge es msedge.exe). Compruebe antes el nombre real con tasklist.

tasklist | findstr /i "edge"
taskkill /im msedge.exe

Si intenta terminar desde un Símbolo del sistema normal un proceso que se ejecuta como administrador, el resultado es “Acceso denegado”.

“El directorio no está vacío”

rmdir (rd) no elimina una carpeta que todavía tiene contenido. Añada /s para eliminarla con todo lo que contiene.

rmdir /s /q "C:\work\old"

Con /q se elimina sin confirmación. No va a la Papelera de reciclaje y no se puede deshacer, así que revise bien la ruta. Si sigue fallando con /s, algún archivo de dentro está siendo usado por otro proceso (ver arriba).

“Ya existe el subdirectorio o el archivo …”

La carpeta que intentó crear con mkdir (md), o un archivo con el mismo nombre, ya existe. En un archivo por lotes, créela solo cuando no exista.

if not exist "C:\work\logs\" mkdir "C:\work\logs"

Añadir \ al final de la ruta comprueba que existe como carpeta (comprobar si existen archivos y carpetas).

“Existe un nombre de archivo duplicado o no se encuentra el archivo”

ren (rename) muestra este mensaje cuando ya existe un archivo con el nombre nuevo o no se encuentra el archivo original. Compruebe ambos nombres con dir /b. ren no puede mover archivos a otra carpeta; para eso use move.

No se encuentra la etiqueta de goto o call

Cuando no se encuentra la etiqueta de goto etiqueta o call :etiqueta, el archivo por lotes se detiene con un error que indica que no se encuentra la etiqueta.

  • El nombre de la etiqueta está mal escrito (:end y goto edn, por ejemplo).
  • El archivo por lotes usa finales de línea solo LF. Cuando herramientas de Linux o la configuración de Git convierten los finales de línea a LF, puede que las etiquetas no se encuentren bien. Vuelva a guardar el archivo con finales de línea CRLF.

Puede listar las etiquetas de un archivo con número de línea:

findstr /n "^:" "build.bat"

“El sistema no puede encontrar la unidad especificada”

Aparece al cambiar a una unidad que no existe, como D:. Causas típicas: una unidad externa sin conectar o una unidad de red desconectada (que además puede no verse desde una ventana ejecutada como administrador). Si la letra de unidad existe pero no tiene medio, el mensaje es “El dispositivo no está listo.”.

net use

net use muestra las unidades de red asignadas y su estado.

“La línea de entrada es demasiado larga”

Tras expandir las variables, una línea superó el límite del Símbolo del sistema de 8191 caracteres. Suele ocurrir cuando un archivo por lotes ejecuta set PATH=%PATH%;... repetidamente y el PATH no deja de crecer. Con setlocal, los cambios hechos en el archivo por lotes se deshacen al terminar, así que el PATH no sigue creciendo (setlocal / endlocal).

“No se ha definido la variable de entorno …”

Aparece al intentar mostrar con set nombre una variable que no existe. Más que un error, indica que la variable no está definida. En un archivo por lotes, use if defined para comprobar si una variable existe.

if defined JAVA_HOME (echo JAVA_HOME esta definida) else (echo JAVA_HOME no esta definida)

El mensaje aparece con caracteres ilegibles

Si el mensaje de error aparece con � o caracteres extraños, la página de códigos (la codificación usada para mostrar el texto) no coincide.

Detectar errores en un archivo por lotes

Además del mensaje en pantalla, la mayoría de los comandos indican si han tenido éxito o no con un código de salida (%errorlevel%). En un archivo por lotes, comprobarlo es más fiable.

copy "a.txt" "backup\" >nul 2>&1 || echo Error al copiar

2>&1 descarta también los mensajes de error (salida de error estándar), y || ejecuta el siguiente comando solo si el anterior falló.

#Símbolo del sistema #Archivos por lotes #Errores #Solución de problemas