robocopy - Advanced Copy

When you want to back up or mirror folders, copy and xcopy can fall short.

ROBOCOPY (Robust File Copy) is a powerful file copy command built into Windows. It offers mirroring, incremental copying, retry control and logging for dependable copies.

This article covers robocopy from the basics to practical backup use, with sample code.

If you just want to copy a folder with everything in it, robocopy source destination /E is the basic form. To make the destination an exact copy, use /MIR. To judge the result, see the exit codes section.

robocopy syntax

ROBOCOPY source destination [file] [options]

Basic example

robocopy C:\Source D:\Backup

－ □ ×

Command Prompt

Microsoft Windows [Version xx.x.xxxxx.xxx]

(c) 2026 Ribbit App Development All rights reserved.

 

C:\users\user>robocopy C:\Source D:\Backup

-------------------------------------------------------------------------------

ROBOCOPY :: Robust File Copy for Windows

-------------------------------------------------------------------------------

Started : Wednesday, March 11, 2026 10:00:00 AM

Source : C:\Source\

Dest : D:\Backup\

Files : .

Total Copied Skipped Mismatch FAILED Extras

Dirs : 3 1 2 0 0 0

Files : 5 5 0 0 0 0

C:\users\user>

Main options

Copy options

Selection options

Retry options

Log options

Copy including subfolders (/E)

The /E option copies subfolders recursively, including empty ones.

robocopy C:\Source D:\Backup /E

Mirroring (/MIR)

The /MIR option reproduces the source folder structure exactly at the destination (it combines /E and /PURGE). Files that exist only in the destination are deleted.

robocopy C:\Source D:\Backup /MIR

Test run (/L)

With /L, nothing is copied; robocopy only shows which files would be copied or deleted.

robocopy C:\Source D:\Backup /MIR /L

Speed up copying (/MT)

/MT:n copies several files in parallel. It is especially effective when there are many small files.

robocopy C:\Source D:\Backup /E /MT:16

Logging

How to record robocopy results in a log file.

robocopy C:\Source D:\Backup /E /LOG:"C:\Logs\backup.log" /TEE /NP

To append to the log, use /LOG+:.

robocopy C:\Source D:\Backup /E /LOG+:"C:\Logs\backup.log" /TEE /NP

Exclude files and folders

Exclude files (/XF)

robocopy C:\Source D:\Backup /E /XF *.tmp *.log

Exclude folders (/XD)

robocopy C:\Source D:\Backup /E /XD "C:\Source\temp" "C:\Source\.git"

Practical example: automatic backup batch

A practical backup batch file using robocopy.

@echo off
setlocal

rem Backup settings
rem Note: the format of %DATE% depends on regional settings. This example assumes yyyy/mm/dd.
set SOURCE=C:\Users\user\Documents
set DEST=D:\Backup\Documents
set LOGFILE=D:\Backup\Logs\backup_%DATE:~0,4%%DATE:~5,2%%DATE:~8,2%.log

rem Create the log folder if it does not exist
if not exist "D:\Backup\Logs" mkdir "D:\Backup\Logs"

echo Starting backup...
echo Source: %SOURCE%
echo Destination: %DEST%

robocopy "%SOURCE%" "%DEST%" /MIR /R:3 /W:5 /LOG+:"%LOGFILE%" /TEE /NP /XD ".git" "node_modules"

rem Check the exit code
IF %ERRORLEVEL% LSS 8 (
    echo Backup completed successfully.
) ELSE (
    echo An error occurred. Please check the log.
)

endlocal

robocopy exit codes

robocopy returns its own exit codes. Unlike most commands, a non-zero code can still mean success. The code is a combination of these bits:

For example, exit code 3 means 1 (files copied) + 2 (extra files found). 0 means nothing needed to be copied (everything is identical).

robocopy vs. xcopy

Microsoft has deprecated xcopy and recommends robocopy, so prefer robocopy for new batch files.

Summary

This article explained how to use the robocopy command.

robocopy is a powerful copy tool built into Windows. For backups in particular, combining mirroring, logging and retry control gives you a dependable setup.

Related articles

Practice question