reg - Work with the Registry

The reg command works with the Windows registry. It lets you view, add, change, and delete keys and values from Command Prompt or a batch file, just as you would in Registry Editor (regedit).

It is useful when you want to automate a settings change or apply the same setting to several computers.

Registry Basics

The registry is a database that stores settings for Windows and applications. It consists of keys, which work like folders, and the values (name, type, and data) stored in them.

With the reg command, you specify a key with a path like this:

HKEY_CURRENT_USER\Software\MyApp

For the root key at the start of the path, you can use these abbreviations:

Basic Syntax of the reg Command

reg <operation> <key name> [options]

The available operations are listed below. This article focuses on the commonly used query, add, delete, export, and import.

Display Keys and Values (reg query)

Display the contents of a key

reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Run"

This lists the values and subkeys directly under the specified key. This key holds the apps that start automatically when you sign in.

－ □ ×

Command Prompt

Microsoft Windows [Version xx.x.xxxxx.xxx]

(c) 2026 Ribbit App Development All rights reserved.

 

C:\users\user>reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Run"

HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run

OneDrive REG_SZ “C:\Users\taro\AppData\Local\Microsoft\OneDrive\OneDrive.exe” /background

C:\users\user>

Each line shows the value name, the value type, and the data, in that order.

Display only a specific value

Use /v to specify the value name.

reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v ProductName

－ □ ×

Command Prompt

Microsoft Windows [Version xx.x.xxxxx.xxx]

(c) 2026 Ribbit App Development All rights reserved.

 

C:\users\user>reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v ProductName

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion

ProductName REG_SZ Windows 10 Pro

C:\users\user>

おすすめ書籍※ 広告を含む場合があります

中小企業経営者のためのRPA入門 RPA導入を成功させる方法

60分でわかる！ AIエージェント　超入門

コマンドラインの黒い画面が怖いんです。

知識・才能ゼロでもらく～に月10万円稼ぐ! よくわかるAI副業超入門

To display the default value, which has no name, use /ve instead of /v.

Display or search including subkeys

Add /s to display everything, including subkeys. Combine it with /f to search for text.

reg query "HKCU\Software\MyApp" /s

reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Run" /s /f Chrome

query options

Value Types

Every value has a type, which you specify with /t in reg add.

Add or Change Keys and Values (reg add)

reg add <key name> [/v name | /ve] [/t type] [/d data] [/f]

If the key does not exist, it is created along with any intermediate keys. If the specified value already exists, it is overwritten after confirmation (add /f to overwrite without confirmation).

reg add "HKCU\Software\MyApp" /v UserName /t REG_SZ /d "taro"

reg add "HKCU\Software\MyApp" /v Enabled /t REG_DWORD /d 1

When it succeeds, the message “The operation completed successfully.” appears.

－ □ ×

Command Prompt

Microsoft Windows [Version xx.x.xxxxx.xxx]

(c) 2026 Ribbit App Development All rights reserved.

 

C:\users\user>reg add "HKCU\Software\MyApp" /v Enabled /t REG_DWORD /d 1

The operation completed successfully.

C:\users\user>

add options

Example: Show file extensions

The setting that shows file extensions in File Explorer is stored in a value named HideFileExt. Setting it to 0 shows extensions.

reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v HideFileExt /t REG_DWORD /d 0 /f

The setting takes effect after you reopen File Explorer or sign in again.

Delete Keys and Values (reg delete)

reg delete "HKCU\Software\MyApp" /v UserName /f

reg delete "HKCU\Software\MyApp" /f

Back Up and Restore (reg export / reg import)

Before you change the registry, write the target key to a .reg file.

reg export "HKCU\Software\MyApp" "%USERPROFILE%\Desktop\myapp-backup.reg"

If a file with the same name exists, you are asked whether to overwrite it. Add /y to overwrite without confirmation.

reg import "%USERPROFILE%\Desktop\myapp-backup.reg"

Using It in Batch Files

Read a value into a variable

The output of reg query has the form value name type data. You can split it on whitespace with for /f and extract the data.

@echo off

set KEY=HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion

for /f "tokens=2*" %%a in ('reg query "%KEY%" /v ProductName ^| find "ProductName"') do set PRODUCT=%%b

echo Product name: %PRODUCT%

tokens=2* assigns the second item (the type) to %%a and everything after it (the data) to %%b. Even if the data contains spaces, %%b captures it all. However, if the value name itself contains spaces, the item positions shift and this method does not work.

Check whether a key or value exists

reg query returns exit code 1 if the target does not exist. You can use this to check for existence.

@echo off

reg query "HKCU\Software\MyApp" /v Enabled >nul 2>&1
if errorlevel 1 (
  echo No setting found. Registering the default.
  reg add "HKCU\Software\MyApp" /v Enabled /t REG_DWORD /d 1 /f >nul
) else (
  echo Setting found.
)

>nul 2>&1 suppresses both standard output and error output.

32-bit and 64-bit Registry Views

On 64-bit Windows, some keys such as HKLM\SOFTWARE are split so that 32-bit apps see a separate location (WOW6432Node). The reg command has options to choose which view to operate on.

reg query "HKLM\SOFTWARE\MyApp" /reg:32

You may need to specify this when working with settings that a 32-bit app reads and writes.

Summary

Related Articles

Practice Questions