reg - レジストリを操作する

regコマンドは、Windows のレジストリを操作するコマンドです。レジストリエディター（regedit）で行うキーや値の確認・追加・変更・削除を、コマンドプロンプトやバッチファイルから実行できます。

設定変更を自動化したい、複数のパソコンに同じ設定を配りたい、といった場面で役立ちます。

レジストリの基本

レジストリは、Windows やアプリケーションの設定を保存しているデータベースです。フォルダーのようなキーと、その中に保存される値（名前・種類・データ）で構成されています。

regコマンドでは、キーを次のようなパスで指定します。

HKEY_CURRENT_USER\Software\MyApp

先頭の部分（ルートキー）は、次の略称が使えます。

regコマンドの基本構文

reg <操作> <キー名> [オプション]

操作には次のものがあります。この記事では、よく使うquery・add・delete・export・importを中心に解説します。

キーや値を表示する（reg query）

キーの内容を表示する

reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Run"

指定したキーの直下にある値と、サブキーが一覧表示されます。このキーには、サインイン時に自動起動するアプリが登録されています。

－ □ ×

コマンド プロンプト

Microsoft Windows [Version xx.x.xxxxx.xxx]

(c) 2026 Ribbit App Development All rights reserved.

 

C:\users\user>reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Run"

HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run

OneDrive REG_SZ “C:\Users\taro\AppData\Local\Microsoft\OneDrive\OneDrive.exe” /background

C:\users\user>

表示は「値の名前」「値の種類」「データ」の順に並びます。

特定の値だけを表示する

/vで値の名前を指定します。

reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v ProductName

－ □ ×

コマンド プロンプト

Microsoft Windows [Version xx.x.xxxxx.xxx]

(c) 2026 Ribbit App Development All rights reserved.

 

C:\users\user>reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v ProductName

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion

ProductName REG_SZ Windows 10 Pro

C:\users\user>

おすすめ書籍※ 広告を含む場合があります

中小企業経営者のためのRPA入門 RPA導入を成功させる方法

60分でわかる！ AIエージェント　超入門

コマンドラインの黒い画面が怖いんです。

知識・才能ゼロでもらく～に月10万円稼ぐ! よくわかるAI副業超入門

名前の付いていない既定の値を表示するときは、/vの代わりに/veを指定します。

サブキーも含めて表示・検索する

/sを付けると、サブキーも含めてすべて表示します。/fと組み合わせると、文字列で検索できます。

reg query "HKCU\Software\MyApp" /s

reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Run" /s /f Chrome

query のオプション

値の種類

値には「種類」があり、reg addの/tで指定します。

キーや値を追加・変更する（reg add）

reg add <キー名> [/v 名前 | /ve] [/t 種類] [/d データ] [/f]

キーが存在しなければ、途中のキーも含めて作成されます。指定した値がすでに存在する場合は、確認のうえ上書きされます（/fを付けると確認なしで上書きします）。

reg add "HKCU\Software\MyApp" /v UserName /t REG_SZ /d "taro"

reg add "HKCU\Software\MyApp" /v Enabled /t REG_DWORD /d 1

実行に成功すると、「この操作を正しく終了しました。」と表示されます。

－ □ ×

コマンド プロンプト

Microsoft Windows [Version xx.x.xxxxx.xxx]

(c) 2026 Ribbit App Development All rights reserved.

 

C:\users\user>reg add "HKCU\Software\MyApp" /v Enabled /t REG_DWORD /d 1

この操作を正しく終了しました。

C:\users\user>

add のオプション

例：ファイルの拡張子を表示する

エクスプローラーでファイルの拡張子を表示する設定は、HideFileExtという値で管理されています。0にすると拡張子が表示されます。

reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v HideFileExt /t REG_DWORD /d 0 /f

設定は、エクスプローラーを開き直すか、サインインし直すと反映されます。

キーや値を削除する（reg delete）

reg delete "HKCU\Software\MyApp" /v UserName /f

reg delete "HKCU\Software\MyApp" /f

バックアップと復元（reg export / reg import）

レジストリを変更する前に、対象のキーを.regファイルに書き出しておきましょう。

reg export "HKCU\Software\MyApp" "%USERPROFILE%\Desktop\myapp-backup.reg"

同名のファイルが存在する場合は上書きの確認が出ます。確認なしで上書きするには/yを付けます。

reg import "%USERPROFILE%\Desktop\myapp-backup.reg"

バッチファイルで使う

値を変数に取り込む

reg queryの出力は値の名前 種類 データの形式です。for /fで空白区切りに分解すると、データ部分を取り出せます。

@echo off

set KEY=HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion

for /f "tokens=2*" %%a in ('reg query "%KEY%" /v ProductName ^| find "ProductName"') do set PRODUCT=%%b

echo 製品名: %PRODUCT%

tokens=2*は、2 番目の項目（種類）を%%a、それ以降すべて（データ）を%%bに代入する指定です。データに空白が含まれていても、%%bにまとめて取得できます。ただし、値の名前自体に空白が含まれる場合は項目の位置がずれるため、この方法は使えません。

キーや値が存在するか確認する

reg queryは、対象が存在しないと終了コード 1 を返します。この性質を使うと、存在確認ができます。

@echo off

reg query "HKCU\Software\MyApp" /v Enabled >nul 2>&1
if errorlevel 1 (
  echo 設定がありません。初期値を登録します。
  reg add "HKCU\Software\MyApp" /v Enabled /t REG_DWORD /d 1 /f >nul
) else (
  echo 設定が見つかりました。
)

>nul 2>&1は、標準出力とエラー出力を表示しない指定です。

32 ビット／64 ビットのレジストリビュー

64 ビット版の Windows では、HKLM\SOFTWAREなど一部のキーで、32 ビットのアプリが参照するレジストリが別の場所（WOW6432Node）に分けられています。regコマンドには、どちらのビューを操作するかを指定するオプションがあります。

reg query "HKLM\SOFTWARE\MyApp" /reg:32

32 ビットのアプリが読み書きする設定を扱うときに、指定が必要になることがあります。

まとめ

関連記事

練習問題