cipher - フォルダの暗号化と空き領域の消去
目次
cipherコマンドは、NTFS ドライブ上のファイルやフォルダの暗号化(EFS)を操作するコマンドです。さらに、削除したファイルの痕跡を、ドライブの空き領域から上書き消去することもできます。
この記事では、次の 2 つの使い方を中心に解説します。
- フォルダやファイルを暗号化・復号する(
/e/d) - 空き領域に残った削除済みデータを消去する(
/w)
基本的な使い方
cipher [/e | /d] [/s:フォルダ] [/a] [/i] [/h] [パス ...]
cipher /w:フォルダ
cipher /x[:暗号化ファイル] 出力ファイル名
| オプション | 説明 |
|---|---|
/e | 指定したフォルダを暗号化する。以降にそのフォルダへ追加するファイルも暗号化される |
/d | 指定したフォルダの暗号化を解除する |
/s:フォルダ | 指定したフォルダと、そのすべてのサブフォルダを対象にする |
/a | フォルダだけでなく、ファイルにも操作を行う |
/i | エラーが起きても処理を続ける |
/h | 隠しファイルやシステムファイルも処理対象に含める |
/w:フォルダ | ボリュームの未使用領域に残ったデータを上書きして消去する |
/x | 暗号化に使った証明書と秘密鍵をファイルにバックアップする |
暗号化の状態を確認する
引数なしで実行すると、カレントフォルダにあるファイルとフォルダの暗号化状態が一覧で表示されます。
行頭の文字が暗号化の状態を表します。
| 表示 | 意味 |
|---|---|
U | 暗号化されていない(Unencrypted) |
E | 暗号化されている(Encrypted) |
上の出力は一例です。メッセージの文言は Windows のバージョンや表示言語によって異なります。
暗号化の前に知っておくこと
cipher による暗号化は EFS(Encrypting File System) という機能を使います。使う前に、次の点を確認してください。
- NTFS のドライブでのみ使えます。FAT32 や exFAT のドライブ(USB メモリなど)では暗号化できません
- Windows の Home エディションでは EFS を利用できません。Pro、Enterprise、Education などのエディションが必要です
- 暗号化されたファイルは、暗号化に使った証明書と秘密鍵を持つユーザーだけが開けます。持たないユーザーや、別の OS からは読み取れません
- 暗号化したファイルを FAT32 や exFAT など NTFS 以外のドライブにコピーすると、コピー先は暗号化されていない(平文の)ファイルになります
- ReFS のドライブでも EFS は使えません
EFS の鍵は、ユーザーアカウントに紐づいています。Windows の再インストールやアカウントの削除などで鍵を失うと、暗号化したファイルを二度と開けなくなります。証明書は初めて暗号化したときに自動で作成されるため、暗号化したらすぐに、後述の「鍵をバックアップする」を行ってください。
フォルダを暗号化する
フォルダを指定して/eを実行すると、そのフォルダが暗号化の対象になります。
cipher /e "C:\work\secret"
この状態では、フォルダに今後追加するファイルが自動的に暗号化されます。フォルダの中にすでにあるファイルも暗号化したい場合は、/sと/aを付けます。
cipher /e /a /s:"C:\work\secret"
エクスプローラーでは、暗号化されたファイルの名前が既定で緑色の文字で表示されます。
親フォルダが暗号化されていないと、暗号化したファイルを編集したときに、ファイルが復号されて保存されることがあります。ファイルだけでなく、それを含むフォルダも暗号化しておくと安全です。
C:\My Documentsのように空白を含むパスは、"で囲みます。/s:の場合は/s:"C:\My Documents"のように、/s:の後ろを囲みます。
暗号化を解除する
暗号化を解除するときは、/eの代わりに/dを使います。
cipher /d /a /s:"C:\work\secret"
鍵をバックアップする
暗号化に使った証明書と秘密鍵を、.pfxファイルとして書き出します。実行するとパスワードの入力を求められ、そのパスワードで保護されたファイルが作成されます。まだ一度も暗号化していない場合は、先にフォルダを暗号化して証明書を作成してください。
cipher /x "%USERPROFILE%\Desktop\efs-backup"
デスクトップにefs-backup.pfxが作成されます。このファイルは、暗号化したファイルと別の場所(外付けドライブなど)に保管してください。同じドライブに置いておくと、そのドライブが壊れたときに両方を失います。
.pfxファイルには秘密鍵が含まれており、パスワードが分かれば暗号化したファイルを開けます。保管場所とパスワードの管理には注意してください。
削除したデータを完全に消去する(/w)
ファイルを削除しても、ディスク上のデータはすぐには消えません。空き領域として扱われるだけで、データ復旧ソフトを使うと復元できる場合があります。
cipher /wは、ボリュームの未使用領域を上書きして、削除済みのデータを復元しにくくするためのオプションです。PC の譲渡や廃棄の前などに使います。
cipher /w:C:\
/w:に指定するのは、消去したいボリューム上の任意のフォルダです。そのフォルダが含まれるボリューム全体の未使用領域が対象になります。
実行すると、空き領域に 0x00、0xFF、乱数の順に、計 3 回の上書きを行います。/wは他のオプションを無視するため、/eなどと併記しても意味はありません。ドライブの容量や空き領域が大きいほど、数十分から数時間かかることがあります。
/wが消去するのは、すでに削除されて未使用になった領域だけです。現在あるファイルはそのままで、削除はされません。ただし、実行中はドライブの空き領域を一時的に使い切るため、他の作業はなるべく止めておきましょう。
約 1 KB 未満の小さなファイルのデータは、NTFS の管理領域(MFT)に保存されるため、/wでは上書きされない場合があります。
SSD では、書き込み先を分散させる仕組み(ウェアレベリング)のため、上書きしても元のデータが残る領域が出る可能性があります。SSD のデータを確実に消したい場合は、使い始めから BitLocker などでドライブ全体を暗号化しておくか、メーカーが提供する消去ツール(Secure Erase など)を使うことをおすすめします。
バッチファイルでの使い方
暗号化の前にフォルダの存在確認を行い、暗号化後に結果を表示するバッチファイルの例です。
@echo off
set "TARGET=%~1"
if "%TARGET%"=="" (
echo 使い方: encrypt-folder.cmd フォルダのパス
exit /b 1
)
if not exist "%TARGET%\" (
echo フォルダが見つかりません: "%TARGET%"
exit /b 1
)
cipher /e /a /s:"%TARGET%"
echo.
echo 結果を確認してください。E が付いていれば暗号化されています。
cipher "%TARGET%"
引数やフォルダの存在確認については、
とを参照してください。cipherの終了コードは公式には定義されていません。NTFS 以外のドライブなどで失敗しても、終了コードだけでは判別できない場合があるため、上の例のように出力や暗号化状態(E)を確認してください。
まとめ
| やりたいこと | コマンド |
|---|---|
| 暗号化の状態を確認する | cipher |
| フォルダを暗号化する | cipher /e "フォルダ" |
| 既存のファイルも含めて暗号化する | cipher /e /a /s:"フォルダ" |
| 暗号化を解除する | cipher /d /a /s:"フォルダ" |
| 証明書と鍵をバックアップする | cipher /x "出力ファイル名" |
| 削除済みデータを消去する | cipher /w:C:\ |