sc - サービスを操作する

scコマンドは、Windows のサービスを操作するコマンドです。サービスとは、サインインしなくてもバックグラウンドで動き続けるプログラム（印刷、Windows Update、ネットワーク機能など）のことです。

scを使うと、サービスの状態確認、起動・停止、スタートアップの種類（自動・手動・無効）の変更をコマンドだけで行えます。GUI の「サービス」画面（services.msc）を開かなくても済むため、バッチファイルに組み込むのにも向いています。

scコマンドの基本構文

sc <コマンド> <サービス名> [オプション]

最初の引数に「何をするか」を指定し、続けて対象のサービス名を指定します。主なコマンドは次のとおりです。

サービス名と表示名

サービスには、services.mscで見える表示名（例：Print Spooler）とは別に、コマンドで指定するサービス名（例：Spooler）があります。scで指定するのはサービス名のほうです。

sc queryの結果に、サービス名（SERVICE_NAME）と表示名（DISPLAY_NAME）が並んで表示されるので、対応を確かめられます。

サービスの状態を確認する

サービス名を指定してsc queryを実行します。

sc query Spooler

－ □ ×

コマンド プロンプト

Microsoft Windows [Version xx.x.xxxxx.xxx]

(c) 2026 Ribbit App Development All rights reserved.

 

C:\users\user>sc query Spooler

SERVICE_NAME: Spooler

TYPE : 110 WIN32_OWN_PROCESS (interactive)

STATE : 4 RUNNING

(STOPPABLE, NOT_PAUSABLE, ACCEPTS_SHUTDOWN)

WIN32_EXIT_CODE : 0 (0x0)

SERVICE_EXIT_CODE : 0 (0x0)

CHECKPOINT : 0x0

WAIT_HINT : 0x0

C:\users\user>

STATEが現在の状態です。主な値は次のとおりです。

サービス名を付けずにsc queryだけを実行すると、実行中のサービスが一覧で表示されます。停止中のものも含めて表示するには、state= allを指定します。

sc query type= service state= all

一覧が長いときは、moreやfindと組み合わせると読みやすくなります。

sc query type= service state= all | find "SERVICE_NAME"

サービスの構成を確認する

sc qc（query config）で、起動の種類や実行ファイルのパスを確認できます。

sc qc Spooler

START_TYPEに起動の種類が、BINARY_PATH_NAMEにサービスの実行ファイルが表示されます。

サービスを起動・停止する

起動はsc start、停止はsc stopです。

sc start Spooler
sc stop Spooler

sc stopは停止の要求を送るだけで、停止が完了するのを待ちません。実行直後はSTOP_PENDINGと表示されることがあり、少し待ってからsc queryでSTOPPEDになったかを確かめます。

サービスを再起動する

scに再起動コマンドはないので、停止して起動し直します。停止の完了を待つためにtimeoutを挟みます。

@echo off

sc stop Spooler
timeout /t 3 /nobreak >nul
sc start Spooler

停止に時間がかかるサービスでは、3 秒では足りないことがあります。確実に待ちたいときは、後述の「状態を待つ」方法を使ってください。

net start／net stopとの違い

net start サービス名とnet stop サービス名でも、サービスを起動・停止できます。

net stop Spooler
net start Spooler

net stopは、サービスが停止するまで待ってから戻ります。また、そのサービスに依存している他のサービスも、確認のうえ一緒に停止します。単純に止めて起動したいだけならnetのほうが手軽で、状態の確認や構成の変更までしたいならscが向いています。

スタートアップの種類を変更する

sc configのstart=で、Windows 起動時の動作を変更できます。

sc config Spooler start= demand

エラーと対処法

scが失敗すると、[SC] OpenService FAILED 1060:のように、エラー番号付きのメッセージが表示されます。

エラー番号の意味は、net helpmsg 1060のようにnet helpmsgで確認できます。

バッチファイルで状態を判定する

sc queryの出力をfindで検索すると、サービスが動いているかを判定できます。

@echo off

sc query Spooler | find "RUNNING" >nul
if errorlevel 1 (
  echo Print Spooler は停止しています。
) else (
  echo Print Spooler は実行中です。
)

findは一致する行があれば終了コード 0、なければ 1 を返すため、if errorlevel 1で「見つからなかった」場合を分岐できます。STATEの値は表示言語に影響されない英語表記なので、日本語環境でも同じ書き方で動作します。

状態を待つ

起動や停止の完了を待つには、状態が目的の値になるまで繰り返し確認します。

@echo off

sc stop Spooler >nul

:wait
sc query Spooler | find "STOPPED" >nul
if errorlevel 1 (
  timeout /t 1 /nobreak >nul
  goto wait
)

echo 停止しました。

新しいサービスを登録・削除する

sc createで、自作のプログラムなどをサービスとして登録できます。binPath=には実行ファイルのパスを指定します。

sc create MyService binPath= "C:\tools\myservice.exe" start= demand

不要になったらsc deleteで登録を削除します。

sc delete MyService

なお、通常のプログラムやバッチファイルは、そのままではサービスとして動作しません。サービスとして登録するには、サービス制御マネージャーからの要求に応答できる実装が必要です。

まとめ

関連記事

練習問題