prompt - プロンプト表示の変更

にメンテナンス済み
目次

promptコマンドは、コマンドプロンプトの行頭に表示される文字列(プロンプト)を変更するコマンドです。

初期状態ではC:\Users\taro>のように「現在のフォルダー + >」が表示されますが、promptを使うと、時刻やドライブ名を表示したり、入力欄を次の行に移したりと、自分の使いやすい形に変えられます。

promptコマンドの基本構文

prompt [<文字列>]

<文字列>には、普通の文字と、$で始まる特殊記号を組み合わせて指定します。引数を省略すると、既定の設定に戻ります。

prompt $P$G

$Pは現在のフォルダー、$Gは>を表します。つまり、これが既定のプロンプトと同じ形です。

特殊記号の一覧

記号表示される内容
$P現在のドライブとフォルダー(例: C:\Users\taro)
$N現在のドライブ(例: C:)
$G>
$L<
$C(
$F)
$+pushdスタックの深さの数だけ + を表示
$D現在の日付(形式は地域設定による)
$T現在の時刻
$VWindows のバージョン
$_改行
$Sスペース
$$$
$Q=
$B|(パイプ記号)
$A&
$Eエスケープ文字(ASCII コード 27。色の指定に使う)
$Hバックスペース(直前の 1 文字を消す)
$M について

$Mは、現在のドライブがネットワークドライブの場合にその接続先(リモート名)を表示する記号です。ネットワークドライブ以外では何も表示されません。

使用例

入力欄を次の行にする

フォルダー階層が深いと、プロンプトが長くなって入力できる幅が狭くなります。$_で改行すると、入力欄を次の行に移せます。

prompt $P$_$G$S
- □ ×
コマンド プロンプトのアイコン
コマンド プロンプト
Microsoft Windows [Version xx.x.xxxxx.xxx]
(c) 2026 Ribbit App Development All rights reserved.
 
C:\Users\taro\Documents\Projects\sample>prompt $P$_$G$S
C:\Users\taro\Documents\Projects\sample>

実行後は、次のように表示されます。

C:\Users\taro\Documents\Projects\sample
> 

時刻を表示する

prompt $T$S$P$G

コマンドを実行した時刻が分かるので、処理にかかった時間を知りたいときなどに便利です。$Tの表示は、12:34:56.78のように1/100 秒まで含まれます。

日付と時刻を表示する

prompt [$D$S$T]$S$P$G

文字を色付きにする(ANSI エスケープシーケンス)

$Eと ANSI エスケープシーケンスを組み合わせると、プロンプトに色を付けられます。

prompt $E[32m$P$E[0m$G
  • $E[32m: 以降の文字を緑色にする
  • $E[0m: 色を元に戻す
色が表示されない場合

色の指定は、Windows 10 以降のコマンドプロンプトや Windows Terminal など、ANSI エスケープシーケンスに対応した環境で使えます。非対応の環境では、←[32mのような文字がそのまま表示されることがあります。

設定は現在のウィンドウだけ有効

promptで変更した内容は、そのコマンドプロンプトのウィンドウを閉じると元に戻ります。内部的には、PROMPTという環境変数を書き換えているためです。現在の設定は、次のコマンドで確認できます。

echo %PROMPT%

設定を保存して、毎回使う

新しく開いたコマンドプロンプトでも同じ表示にしたい場合は、setxコマンドでPROMPT環境変数を保存します。

setx PROMPT "$P$_$G$S"
setx は今開いているウィンドウには反映されません

setxで保存した値は、これから新しく開くコマンドプロンプトで有効になります。今のウィンドウにも反映したい場合は、あわせてprompt $P$_$G$Sも実行してください。

setxの詳しい使い方は、関連記事を参照してください。

元に戻す

引数なしでpromptを実行すると、既定のプロンプトに戻ります。

prompt

setxで保存した設定を削除したい場合は、環境変数の設定画面からPROMPTを削除するか、次のコマンドで既定値($P$G)に上書きします。

setx PROMPT "$P$G"

バッチファイルで使うときの注意

バッチファイルの中でpromptを実行すると、バッチファイルが終了した後も、呼び出し元のウィンドウのプロンプトが変わったままになります。一時的に変更したい場合は、setlocalとendlocalで囲みます。

prompt-test.cmd
@echo off
setlocal

prompt [テスト中]$S$P$G
cmd /k

endlocal

endlocal(または、バッチファイルの終了)で、バッチファイル内の変更は破棄されます。プロンプトは対話的な画面でしか見えないため、ここではcmd /kで新しい画面を開いて確認しています。このバッチファイルを実行すると、プロンプトを[テスト中] C:\...>に変更した新しいcmdが開きます。exitで抜けると、元の表示のままです。

プロンプトを変えるだけなら cmd /k も便利

cmd /kは、バッチファイルから対話的なコマンドプロンプトを開いたままにするための書き方です。cmd /k prompt $P$Gのように、起動時にコマンドを渡すこともできます。

まとめ

やりたいことコマンド
入力欄を次の行にするprompt $P$_$G$S
時刻を表示するprompt $T$S$P$G
緑色で表示するprompt $E[32m$P$E[0m$G
現在の設定を確認するecho %PROMPT%
設定を保存するsetx PROMPT "$P$_$G$S"
既定に戻すprompt

関連記事

練習問題

練習問題

プロンプトに現在の時刻を表示するための特殊記号はどれでしょうか?

正しいものを 1 つ選んでください。

  1. $D
  2. $T
  3. $V

練習問題

promptコマンドで変更したプロンプトを、元の既定の状態に戻すにはどうすればよいでしょうか?

正しいものを 1 つ選んでください。

  1. prompt reset
  2. 引数なしで prompt を実行する
  3. cls を実行する
#コマンドプロンプト #バッチファイル #コマンドライン #コマンド #prompt #カスタマイズ