cmd - コマンドプロセッサを起動する

にメンテナンス済み
目次

cmdコマンドとは

cmdコマンドは、Windows のコマンドプロセッサであるcmd.exeを起動するコマンドです。コマンドプロンプトでcmdと入力すると、新しいコマンドプロンプト(子プロセス)が起動します。

さらに、cmd /c "コマンド"のようにオプションを付けると、コマンドを 1 つ実行して終了する使い方ができます。PowerShell やタスクスケジューラ、forfiles、ショートカットなど、cmd.exe の外から内部コマンド(dir、copy、mklinkなど)を呼び出したい場面で欠かせません。

このページでは、cmdコマンドの基本的な使い方から、主要なオプション、引用符のルールまでをサンプルコード付きで説明します。

cmdコマンドの使い方

cmd [/c | /k] [/s] [/q] [/d] [/a | /u] [/e:on | /e:off] [/f:on | /f:off] [/v:on | /v:off] [<文字列>]
オプション説明
/c <文字列>文字列をコマンドとして実行し、終了します。
/k <文字列>文字列をコマンドとして実行し、終了せずにコマンドプロンプトを残します。
/s/cや/kに続く文字列の引用符の扱いを変更します(後述)。
/qエコーをオフにします(@echo offと同じ効果)。
/t:<BF>背景色と前景色を 16 進数 2 桁で指定します(colorコマンドと同じ形式)。
/dレジストリの AutoRun コマンドの実行を無効にします。
/aパイプやリダイレクトの出力を ANSI 文字で出力します。
/uパイプやリダイレクトの出力を Unicode(UTF-16) で出力します。
/e:on, /e:offコマンド拡張を有効、または無効にします。
/f:on, /f:offファイル名・フォルダ名の補完を有効、または無効にします。
/v:on, /v:off遅延環境変数の展開を有効、または無効にします。

/cと/kは文字列の最後までをコマンドとして扱うため、他のオプションより後ろ(最後)に書く必要があります。

オプションの一覧はcmd /?でも確認できます。

- □ ×
コマンド プロンプトのアイコン
コマンド プロンプト
Microsoft Windows [Version xx.x.xxxxx.xxx]
(c) 2026 Ribbit App Development All rights reserved.
 
C:\users\user>cmd /?

新しいコマンドプロンプトを起動する

オプションを付けずにcmdを実行すると、現在のコマンドプロンプトの中でもう 1 つのcmd.exeが起動します。

- □ ×
コマンド プロンプトのアイコン
コマンド プロンプト
Microsoft Windows [Version xx.x.xxxxx.xxx]
(c) 2026 Ribbit App Development All rights reserved.
 
C:\users\user>cmd
Microsoft Windows [Version 10.0.26100.1]
(c) Microsoft Corporation. All rights reserved.

この状態でexitを実行すると、子のcmd.exeが終了し、元のコマンドプロンプトに戻ります。

子プロセスでの環境変数の変更

子のcmd.exeの中でsetした環境変数は、exitで戻った後の親には反映されません。また、親で設定した環境変数は子に引き継がれます。

終了方法については、以下のページも参照してください。

/cでコマンドを実行して終了する

/cを指定すると、指定したコマンドを実行した後、cmd.exeが終了します。

cmd /c echo Hello
- □ ×
コマンド プロンプトのアイコン
コマンド プロンプト
Microsoft Windows [Version xx.x.xxxxx.xxx]
(c) 2026 Ribbit App Development All rights reserved.
 
C:\users\user>cmd /c echo Hello
Hello

複数のコマンドを実行したい場合は、全体を引用符で囲みます。

cmd /c "cd /d C:\Windows && dir /b *.exe"

&&や|、>などを引用符で囲まずにcmd /cへ渡すと、呼び出し元のシェル(cmd.exeや PowerShell)に先に解釈されてしまいます。詳しくは以下のページを参照してください。

PowerShell から内部コマンドを実行する

mklinkやassocのようにcmd.exeの内部コマンドとして実装されているものは、PowerShell から直接実行できません。cmd /cを使うと実行できます。

cmd /c mklink /d C:\work\assets D:\shared\assets

終了コードを引き継ぐ

cmd /cで実行したコマンドの終了コードは、cmd.exeの終了コードになります。そのため、呼び出し元は%errorlevel%(PowerShell では$LASTEXITCODE)で結果を確認できます。

- □ ×
コマンド プロンプトのアイコン
コマンド プロンプト
Microsoft Windows [Version xx.x.xxxxx.xxx]
(c) 2026 Ribbit App Development All rights reserved.
 
C:\users\user>cmd /c exit 3
- □ ×
コマンド プロンプトのアイコン
コマンド プロンプト
Microsoft Windows [Version xx.x.xxxxx.xxx]
(c) 2026 Ribbit App Development All rights reserved.
 
C:\users\user>echo %errorlevel%
3

exitコマンドに終了コードを指定すると、その値がcmd.exeの終了コードになります。終了コードの扱いは以下のページで解説しています。

チェック

%errorlevel% を誤って set errorlevel=5 のように上書きした場合は、set errorlevel= で変数を削除すると、本来の終了コードが参照されるようになります。

/kでコマンドを実行してウィンドウを残す

/kを指定すると、コマンドを実行した後もcmd.exeが終了せず、コマンドを入力できる状態になります。

cmd /k "cd /d C:\work && dir"

ショートカットのリンク先にcmd /k "C:\scripts\check.cmd"と指定すると、バッチファイルの終了後も結果を確認できます。Win+Rの「ファイル名を指定して実行」から使うこともできます。

新しいウィンドウで起動したい場合は、startコマンドを組み合わせます。

start "ログ監視" cmd /k "title ログ監視 && echo 監視を開始します"

/v:onで遅延展開を有効にする

/v:onを付けて起動すると、環境変数を実行時に展開する遅延展開(!変数名!)が有効になります。バッチファイルのsetlocal enabledelayedexpansionと同じ効果が、コマンドラインでも得られます。

cmd /v:on /c "set "MSG=Hello" && echo !MSG!"
- □ ×
コマンド プロンプトのアイコン
コマンド プロンプト
Microsoft Windows [Version xx.x.xxxxx.xxx]
(c) 2026 Ribbit App Development All rights reserved.
 
C:\users\user>cmd /v:on /c "set "MSG=Hello" && echo !MSG!"
Hello

/v:onを付けずに、同じ行で変数を設定して%MSG%と参照しても、行の解釈時に展開されるため意図した値になりません。遅延展開の詳細は以下のページを参照してください。

その他のオプション

/q エコーをオフにする

/qを付けると、@echo offを指定したのと同じようにコマンドの表示(エコー)が無効になります。

cmd /q /c "echo test"

/d AutoRun を無効にする

レジストリのHKCU\Software\Microsoft\Command Processor(またはHKLM)のAutoRunにコマンドが登録されていると、cmd.exeの起動時にそのコマンドが実行されます。/dを付けると、これを実行せずに起動できます。起動が遅い、あるいは AutoRun が原因で動作がおかしいと疑われる場合の切り分けに使えます。

/u Unicode で出力する

/uを付けると、パイプやリダイレクトによる内部コマンドの出力が Unicode(UTF-16) になります。リダイレクトでファイルに保存すると、UTF-16 のファイルになります。文字コードの詳細は以下のページを参照してください。

引用符のルールに注意する

/cや/kに続く文字列が引用符(")で始まる場合、cmd.exeは次のルールで引用符を処理します。

  1. /sを指定しておらず、かつ次の条件をすべて満たす場合は、引用符をそのまま残します。
    • 引用符がちょうど 2 つである
    • 引用符の間に特殊文字(&<>()@^|)がない
    • 引用符の間に 1 つ以上の空白がある
    • 引用符の間の文字列が、実行可能ファイルの名前である
  2. 上記を満たさない場合は、先頭の引用符と、最後の引用符を取り除き、その間の文字列を実行します。

つまり、スペースを含むパスを実行する場合は、全体をさらに引用符で囲むと確実です。

cmd /c ""C:\Program Files\My App\run.cmd" "引数 1""

/sを付けると、条件の判定を行わずに常に 2 の処理(先頭と最後の引用符を取り除く)になるため、引用符の扱いを予測しやすくなります。

cmd /s /c ""C:\Program Files\My App\run.cmd" "引数 1""
引用符の取り除かれ方を理解しておく

cmd /c "dir" のように単純な場合は問題になりませんが、複数の引用符や & を含む場合は、意図しない箇所の引用符が取り除かれることがあります。うまく動かないときは、全体をもう 1 組の引用符で囲み、/s を付けて確認してください。

cmdコマンドの関連コマンド

練習問題

練習問題

コマンドを 1 つ実行した後に、コマンドプロンプトを終了せず入力待ちの状態で残すオプションはどれですか?

正しいものを 1 つ選んでください。

  1. /c
  2. /k
  3. /q

練習問題

PowerShell からmklinkのようなcmd.exeの内部コマンドを実行するには、どうすればよいですか?

正しいものを 1 つ選んでください。

  1. mklink をそのまま入力する
  2. cmd /c mklink … のように実行する
  3. cmd /q mklink … のように実行する

練習問題

cmdで起動した子のコマンドプロンプトの中でsetした環境変数は、exitで親のコマンドプロンプトに戻った後、どうなりますか?

正しいものを 1 つ選んでください。

  1. 親にも反映される
  2. 親には反映されない
  3. レジストリに保存される
#コマンドプロンプト #バッチファイル #オプション #コマンドライン #コマンド