wevtutil - イベントログを調べる

にメンテナンス済み
目次

wevtutilコマンドは、Windows のイベントログをコマンドプロンプトから確認・エクスポート・消去するためのコマンドです。

PC が突然再起動した、アプリが落ちたといったとき、原因の手がかりはイベントログに記録されていることが多くあります。通常は「イベントビューアー」で確認しますが、wevtutilを使うと、条件を指定して必要なログだけを取り出したり、結果をファイルに保存したり、バッチファイルから自動で調べたりできます。

wevtutilコマンドの基本構文

wevtutil <サブコマンド> [引数] [オプション]

最初に指定するサブコマンドで動作が決まります。よく使うものは次のとおりです。

サブコマンド省略形説明
enum-logselログの名前を一覧表示する
query-eventsqeログのイベントを検索・表示する
get-logglログの設定(最大サイズなど)を表示する
export-logeplログをファイルに書き出す
clear-logclログのイベントを消去する

ここでは主なものを取り上げます。そのほかはwevtutil /?で確認できます。

ログの一覧を表示する(el)

どんなログがあるかは、elで確認できます。

wevtutil el

数百行の一覧が表示されます。代表的なログは次の 3 つです。

ログ名内容
Applicationアプリケーションが記録したイベント
SystemWindows 本体やドライバー、サービスが記録したイベント
Securityサインインの成否など、セキュリティに関するイベント(監査)

特定のログを探すときは、パイプでfindに渡すと便利です。

wevtutil el | find "PowerShell"

イベントを表示する(qe)

qeの後ろにログ名を指定すると、そのログのイベントを表示します。

wevtutil qe System /c:3 /rd:true /f:text
オプション意味
/c:<数>表示するイベントの最大件数
/rd:true新しいイベントから順に表示する(既定は古い順)
/f:text人が読みやすいテキスト形式で表示する(既定は XML)
- □ ×
コマンド プロンプトのアイコン
コマンド プロンプト
Microsoft Windows [Version xx.x.xxxxx.xxx]
(c) 2026 Ribbit App Development All rights reserved.
 
C:\users\user>wevtutil qe System /c:1 /rd:true /f:text
Event[0]:
Log Name: System
Source: Microsoft-Windows-Kernel-Power
Date: 2026-11-22T09:15:30.123
Event ID: 566
Level: Information
Computer: DESKTOP-ABC
Description:
…
C:\users\user>
表示される内容は環境によって異なります

上記の出力はあくまで一例です。イベントの内容や項目の表記は、PC の状態や OS の表示言語によって変わります。

/rd:true を付けないと古いイベントから表示される

/c:だけを指定すると、ログの先頭(最も古いイベント) から指定件数が表示されます。最近の出来事を調べるときは、/rd:trueを必ず併用してください。

条件で絞り込む(/q)

/q:オプションにXPath クエリを指定すると、条件に合うイベントだけを取り出せます。

レベルで絞り込む

エラー(レベル 2)だけを、新しい順に 5 件表示します。

wevtutil qe System /q:"*[System[(Level=2)]]" /c:5 /rd:true /f:text

Levelの値は次のとおりです。

値レベル
1重大
2エラー
3警告
4情報

重大とエラーの両方を取り出すなら、orでつなぎます。

wevtutil qe System /q:"*[System[(Level=1 or Level=2)]]" /c:10 /rd:true /f:text

イベント ID で絞り込む

イベント ID を指定します。たとえば ID 41(Kernel-Power)は、正常にシャットダウンせず再起動したときに記録されます。

wevtutil qe System /q:"*[System[(EventID=41)]]" /c:3 /rd:true /f:text

期間で絞り込む

timediff(@SystemTime)は、イベントが記録されてからの経過時間をミリ秒で返します。直近 24 時間(86,400,000 ミリ秒)のエラーと警告を調べる例です。

wevtutil qe System /q:"*[System[(Level=2 or Level=3) and TimeCreated[timediff(@SystemTime) <= 86400000]]]" /rd:true /f:text

andで条件を組み合わせられます。よく使う期間は次のとおりです。

期間ミリ秒
1 時間3600000
24 時間86400000
7 日604800000

提供元(プロバイダー)で絞り込む

イベントを記録したプロバイダー名で絞り込むこともできます。クエリ全体を"で囲んでいるため、内側は'を使います。

wevtutil qe System /q:"*[System[Provider[@Name='Microsoft-Windows-Kernel-Power']]]" /c:3 /rd:true /f:text
クエリを組み立てるにはイベントビューアーが便利

イベントビューアーの「カスタム ビューの作成」で条件を設定し、「XML」タブを開くと、同じ条件の XPath クエリが表示されます。それを/q:に流用できます。

ログのバックアップ(epl)

eplでログを.evtxファイルに書き出せます。書き出したファイルは、イベントビューアーで開いて確認できます。

wevtutil epl System "%USERPROFILE%\Desktop\System-backup.evtx"

すでに同名のファイルがあるとエラーになるため、上書きしたいときは/ow:trueを付けます。

wevtutil epl System "%USERPROFILE%\Desktop\System-backup.evtx" /ow:true

保存した.evtxファイルの中身は、qeの最後に/lf:trueを付けると、ログ名の代わりにファイルのパスを指定して確認できます。

wevtutil qe "%USERPROFILE%\Desktop\System-backup.evtx" /lf:true /c:3 /rd:true /f:text

ログを消去する(cl)

clで、ログのイベントをすべて削除します。

wevtutil cl Application

/bu:<ファイル>を付けると、消去する前にバックアップを.evtxで保存できます。

wevtutil cl Application /bu:"%USERPROFILE%\Desktop\Application-backup.evtx"
消去したログは元に戻せません

バックアップを取らずに消去すると、障害の調査に必要な記録も失われます。特にSecurityログは、監査の証跡として保持が求められる場合があります。実行する前に、eplまたは/bu:でバックアップを取っておきましょう。

管理者権限が必要なとき

SystemやApplicationの表示は通常の権限でもできますが、Securityログの表示や、ログの消去には管理者として実行したコマンドプロンプトが必要です。権限が足りないと、アクセスが拒否されました。のようなエラーになります。

管理者として起動する方法は、

を参照してください。

バッチファイルでの使い方

直近 24 時間のエラーを、ファイルに保存する例です。

@echo off

set "OUT=%~dp0recent-errors.txt"

wevtutil qe System /q:"*[System[(Level=1 or Level=2) and TimeCreated[timediff(@SystemTime) <= 86400000]]]" /rd:true /f:text > "%OUT%"
if errorlevel 1 (
  echo イベントログの取得に失敗しました。
  exit /b 1
)

echo 結果を保存しました: %OUT%

>(リダイレクト)で結果をファイルに書き出しています。%~dp0はバッチファイル自身があるフォルダーを表します。

該当するイベントがないとき

条件に合うイベントが 1 件もない場合、何も表示されませんが、これはエラーではありません。結果のファイルが空になるだけです。

関連記事

練習問題

練習問題

Systemログの最新のイベントを 5 件、新しいものから順に表示するコマンドはどれでしょうか?

正しいものを 1 つ選んでください。

  1. wevtutil qe System /c:5
  2. wevtutil qe System /c:5 /rd:true
  3. wevtutil el System /c:5

練習問題

ログを消去する前に、バックアップを.evtxファイルとして保存するオプションはどれでしょうか?

正しいものを 1 つ選んでください。

  1. /rd:true
  2. /ow:true
  3. /bu:バックアップ先のファイル
#コマンドプロンプト #バッチファイル #コマンドライン #コマンド #イベントログ #管理者権限 #トラブルシューティング