TASKKILL（プロセス終了）

アプリケーションがフリーズして操作を受け付けなくなったとき、タスクマネージャーで終了する方法が一般的ですが、コマンドプロンプトからも TASKKILL コマンドを使ってプロセスを終了させることができます。

特にバッチファイルで自動化する場合や、複数のプロセスを一括で終了させたい場合に役立ちます。

「とりあえずフリーズしたアプリを終了したい」場合は、taskkill /F /IM アプリ名.exe を実行します。実行ファイル名は tasklist コマンドで確認できます。

TASKKILL の基本構文

TASKKILL [オプション]

主要オプション

プロセス名で終了する（/IM）

プロセス名（実行ファイル名）を指定してプロセスを終了します。

taskkill /IM notepad.exe

－ □ ×

コマンド プロンプト

Microsoft Windows [Version xx.x.xxxxx.xxx]

(c) 2026 Ribbit App Development All rights reserved.

 

C:\users\user>taskkill /IM notepad.exe

成功: プロセス “notepad.exe” (PID 12345) に終了シグナルを送信しました。

C:\users\user>

同じ名前のプロセスが複数起動している場合は、すべてが対象になります。/IM にはワイルドカード（*）も使えます。

taskkill /F /IM chrome*

強制終了（/F）

通常の終了シグナルでプロセスが終了しない場合は、/F オプションで強制終了します。

taskkill /F /IM notepad.exe

－ □ ×

コマンド プロンプト

Microsoft Windows [Version xx.x.xxxxx.xxx]

(c) 2026 Ribbit App Development All rights reserved.

 

C:\users\user>taskkill /F /IM notepad.exe

成功: プロセス “notepad.exe” (PID 12345) は強制終了されました。

C:\users\user>

おすすめ書籍※ 広告を含む場合があります

中小企業経営者のためのRPA入門 RPA導入を成功させる方法

60分でわかる！ AIエージェント　超入門

コマンドラインの黒い画面が怖いんです。

知識・才能ゼロでもらく～に月10万円稼ぐ! よくわかるAI副業超入門

プロセス ID で終了する（/PID）

tasklist コマンドで確認したプロセス ID（PID）を指定して終了させることもできます。

taskkill /PID 12345

複数のプロセスを一度に終了

taskkill /PID 12345 /PID 67890

同じ名前のプロセスのうち 1 つだけを終了したい場合は、tasklist で PID を調べて /PID で指定します。

子プロセスも含めて終了する（/T）

/T オプションを使用すると、指定したプロセスとその子プロセスをまとめて終了できます。

taskkill /F /T /IM cmd.exe

フィルターを使用する（/FI）

/FI オプションを使用すると、特定の条件に一致するプロセスのみを対象にできます。

フィルターの主な条件

応答なしのプロセスを終了

taskkill /F /FI "STATUS eq NOT RESPONDING"

－ □ ×

コマンド プロンプト

Microsoft Windows [Version xx.x.xxxxx.xxx]

(c) 2026 Ribbit App Development All rights reserved.

 

C:\users\user>taskkill /F /FI "STATUS eq NOT RESPONDING"

成功: プロセス “app.exe” (PID 9876) は強制終了されました。

C:\users\user>

ウィンドウタイトルで終了する

WINDOWTITLE フィルターを使うと、ウィンドウのタイトルで対象を絞り込めます。ワイルドカードも使用できます。

taskkill /F /FI "WINDOWTITLE eq *メモ帳*"

メモリ使用量が大きいプロセスを特定する

tasklist /FI "MEMUSAGE gt 500000"

上記で確認した後、必要に応じて対象プロセスを終了させることができます。taskkill にも同じ /FI フィルターを渡せます。

終了できないときの対処

「アクセスが拒否されました」と表示される

他のユーザーのプロセスや、システムが管理するプロセスを終了するには、管理者として実行したコマンドプロンプトが必要です。それでも終了できない保護されたプロセス（セキュリティソフトなど）は、TASKKILL では停止できません。

「プロセスが見つかりませんでした」と表示される

プロセス名の綴りが違うか、すでに終了しています。tasklist で正しいイメージ名を確認してください。

終了コードで結果を判定する

taskkill は成功すると終了コード 0 を返します。対象のプロセスが見つからなかった場合は 128 になるため、バッチファイルでは ERRORLEVEL で分岐できます。

taskkill /F /IM notepad.exe >nul 2>&1
IF %ERRORLEVEL% EQU 0 (
    echo 終了しました。
) ELSE IF %ERRORLEVEL% EQU 128 (
    echo 対象のプロセスは見つかりませんでした。
) ELSE (
    echo 終了できませんでした。管理者権限が必要な可能性があります。
)

リモートコンピューターのプロセスを終了する

/S でコンピューター名、/U でユーザー名、/P でパスワードを指定すると、ネットワーク上の別の PC のプロセスも終了できます（権限とファイアウォールの設定が必要です）。なお、リモートのプロセスに対しては /FI "STATUS ..." などの一部のフィルターが使えません。

taskkill /S PC-SERVER01 /U ユーザー名 /IM notepad.exe /F

実践例

特定のアプリケーションを一括終了

@echo off
echo ブラウザを終了しています...
taskkill /F /IM chrome.exe >nul 2>&1
taskkill /F /IM msedge.exe >nul 2>&1
taskkill /F /IM firefox.exe >nul 2>&1
echo 完了しました。

バッチファイルで安全にプロセスを終了

@echo off
setlocal

set TARGET=notepad.exe

tasklist /FI "IMAGENAME eq %TARGET%" | findstr /I "%TARGET%" >nul
IF %ERRORLEVEL% EQU 0 (
    echo %TARGET% を終了します。
    taskkill /IM %TARGET%
) ELSE (
    echo %TARGET% は実行されていません。
)

endlocal

TASKLIST と TASKKILL の連携

tasklist でプロセスを確認してから taskkill で終了する流れが一般的です。

tasklist /FI "IMAGENAME eq notepad.exe"
taskkill /IM notepad.exe

まとめ

関連記事

練習問題